class Cybandit : Cylonder
{
	Default
	{
		SeeSound "cybandit/sight";
		ActiveSound "cybandit/active";
		PainSound "cybandit/pain";
		DeathSound "cybandit/death";
		Obituary "$OB_CYBANDIT";
	}
	States
	{
	Spawn:
		CYBT ACAB 4 A_Look();
		Loop;
	See:
		CYBT AACCAABB 3 A_Chase();
		Loop;
	Missile:
		CYBT A 10 A_PlaySound("cybandit/attack");
	MissileLoop:
		CYBT A 3 A_FaceTarget();
		CYBT D 3 Bright A_SpawnProjectile("CylonLaser", 12);
		CYBT BAC 2 A_FaceTarget();
		CYBT D 0 A_CPosRefire();
		Loop;
	Pain:
		CYBT A 4;
		CYBT A 4 A_Pain();
		Goto See;
	Death:
		CYBT F 1;
		CYBT C 1 A_Scream();
		CYBT FBFCFBFCFBFCFBFCFBFCFB 1 Bright;
		CYBT F 0 A_SpawnItemEx("GibTenGallonPinkHat", random[SquareGibRandom](-8,8), random[SquareGibRandom](-4,4), 40, random[SquareGibRandom](-4,4), random[SquareGibRandom](-4,4), random[SquareGibRandom](7, 10), 0);
		CYBT F 0 Bright A_SpawnItem("CrystalGibSpawner");
		CYBT F 1 Bright A_SpawnItem("MibSpawnerCylonder");
		CYBT E 0 A_Explode(80,100);
		CYBT E 0 A_Fall();
		CYBT E 1 Bright A_SpawnItemEx("Explosion", random(-20,20), random(-20,20), random(20,30));
		CYBT EEEEEEEE 2 A_SpawnItemEx("Smoke", frandom[SquareEffectRandom](-7.0,7.0), frandom[SquareEffectRandom](-7.0,7.0), 8.0, 0, 0, 2);
		CYBT E -1 A_GiveToTarget("SquareVOEnemiesCylonder", 1);
		Stop;
	}
}
